AmiBroker 控制下單口數、使用下單大師、輸出文字檔

enochyu

程式範例分享 ~ AmiBroker 控制下單口數、使用下單大師、輸出文字檔

1. 
   
2. 
   
3. Title = Date() + " [ Go Order Sample ] by E.Y. @2011/12/29";
   
4. 
   
5. //
   
6. // compute long, short, clearing condition
   
7. //
   
8. _MA3  = Ref( MA( Close, 3 ), -1 );
   
9. _MA22 = Ref( MA( Close, 22 ), -1 );
   
10. Buy   = ( _MA3 > _MA22 );                  // long condition
    
11. Short = ( _MA3 < _MA22 );                  // short condition
    
12. Sell  = Cover = ( TimeNum() > 132000 );    // clearing condition
    
13. 
    
14. //
    
15. // declare signal's parameter
    
16. //
    
17. _LongSharp        = False;    // log long signal
    
18. _ShortSharp       = False;    // log short signal
    
19. _CloseShape       = False;    // log clearing signal
    
20. 
    
21. // ------ >>> START <<< -------------------------------------- //
    
22. // ----------------------------------------------------------- //
    
23. //  此區塊為控制交易口數之程式碼，應該是不少網友的擾 ~ 請笑納
    
24. // ----------------------------------------------------------- //
    
25. // ------ >>> START <<< ------------------------------------- //
    
26. //
    
27. // declare order's parameter
    
28. //
    
29. _ContractUnit     = 1;        // go order contract unit (指定下單口數，亦可由下單機設定)
    
30. _CurrentContracts = 0;        // log go order contracts
    
31. _OrderPrice       = 0;        // log go order price
    
32. for ( i = 0; i < BarCount; i++ )
    
33. {
    
34.     _EntryLong  =      ( Buy[ i ] )
    
35.                   AND !( Sell[ i ] AND Cover[ i ] );
    
36.     _EntryShort =      ( Short[ i ] )
    
37.                   AND !( Sell[ i ] AND Cover[ i ] );
    
38.     // long entry
    
39.     if ( ( _EntryLong ) AND ( _CurrentContracts <= 0 ) )
    
40.     {
    
41.         _CurrentContracts = _ContractUnit;
    
42.         _OrderPrice       = Close[ i ];
    
43.         _LongSharp[ i ]   = True;
    
44.     }
    
45.     // short entry
    
46.     if ( ( _EntryShort ) AND ( _CurrentContracts >= 0 ) )
    
47.     {
    
48.         _CurrentContracts = -1 * _ContractUnit;
    
49.         _OrderPrice       = Close[ i ];
    
50.         _ShortSharp[ i ]  = True;
    
51.     }
    
52.     // clearing
    
53.     if ( ( Sell[ i ] OR Cover[ i ] ) AND ( _CurrentContracts != 0 ) )
    
54.     {
    
55.         _CurrentContracts = 0;
    
56.         _OrderPrice       = Close[ i ];
    
57.         _CloseShape[ i ]  = True;
    
58.     }
    
59. }
    
60. // ------ >>> END <<< ---------------------------------------- //
    
61. // ----------------------------------------------------------- //
    
62. //  此區塊為控制交易口數之程式碼，應該是不少網友的擾 ~ 請笑納
    
63. // ----------------------------------------------------------- //
    
64. // ------ >>> END <<< ---------------------------------------- //
    
65. 
    
66. //
    
67. // sned order command to [ OrderMaster API ]
    
68. // 調用下單大師進行下單
    
69. _OMComAPI   = CreateStaticObject( "OMSignAPI.OMCOMAPI" );
    
70. _OMComAPI.IniDllAndPosition( "EYDEMO", _CurrentContracts );
    
71. _OMDateTime   = Now( 1 ) + " " + StrRight( "00" + floor( Now( 4 ) / 10000 ), 2 )
    
72.                 + ":" + StrRight( "00" + floor( Now( 4 ) / 100 ), 2 )
    
73.                 + ":" + StrRight( "00" + floor( Now( 4 ) % 100 ), 2 );
    
74. _OMEntryPrice = NumToStr( _OrderPrice, 1 );
    
75. _OMComAPI.GoOrder( "EYDEMO", "", _OMDateTime, _CurrentContracts, _OMEntryPrice );
    
76. 
    
77. //
    
78. // output text file for [YasserSoft] auto record
    
79. // 輸出文字檔供下單機讀取，此例為雅策[免費績效紀錄軟體]使用格式，請各位網友是需求自行調整
    
80. _YS_ORDER_CMD = "R:\\YS_TEMP\\EYDEMO.txt";
    
81. if ( ( Now( 4 ) % 2 ) == 0 )
    
82. {
    
83.     _fcsv = fopen( _YS_ORDER_CMD, "w" );
    
84.     _content = StrFormat( "%04.0f/%02.0f/%02.0f %02.0f:%02.0f:%02.0f %g %g %02.0f:%02.0f:%02.0f"
    
85.                           , Year(), Month(), Day()
    
86.                           , Hour(), Minute(), Second()
    
87.                           , _CurrentContracts
    
88.                           , _OrderPrice
    
89.                           , Hour(), Minute(), Second()
    
90.                         );
    
91.     fputs( _content, _fcsv );
    
92.     fclose( _fcsv );
    
93. }
    
94. 
    
95. //
    
96. // draw ma line
    
97. //
    
98. Plot( _MA3, "MA3", colorWhite, styleLine );
    
99. Plot( _MA22, "MA22", colorBlue, styleLine );
    
100. //
     
101. // draw candle line
     
102. //
     
103. Plot( C, "Close", ParamColor( "Color", colorBlack ), styleNoTitle | ParamStyle( "Style" ) | GetPriceStyle() );
     
104. 
     
105. //
     
106. // draw long & short signal
     
107. //
     
108. PlotShapes( _LongSharp * shapeUpArrow + _ShortSharp * shapeDownArrow
     
109.             , IIf( _LongSharp, colorYellow, colorBlue )
     
110.             , 0
     
111.             , IIf( _LongSharp, Low, High )
     
112.             , -80
     
113.           );
     
114. //
     
115. // draw clearing signal
     
116. //
     
117. PlotShapes( _CloseShape * shapeStar
     
118.             , colorWhite
     
119.             , 0
     
120.             , Low
     
121.             , -30
     
122.           );
     
123. 
     

複製代碼

------

祝各位 AmiBroker 戰友順心 ~

轉載至 C.A.B.E.

kilroy

非常感謝 enochyu 大大的幫忙

(每次看到大大的程式碼都覺得很整齊，而且很有邏輯程序感)

小弟來獻醜一下，簡單版的倉位判斷
(我只會非常非常非常簡單的語法來寫而已，汗顏啦)

EntryLongA=IIf(Buy,1,IIf(Short OR Sell OR Cover,-1,0));
EntryLongB=ValueWhen(EntryLongA!=0,EntryLongA,1);

LFlag=IIf(EntryLongB==1,1,0);

EntryShortA=IIf(Short,1,IIf(Buy OR Sell OR Cover,-1,0));
EntryShortB=ValueWhen(EntryShortA!=0,EntryShortA,1);

SFlag=IIf(EntryShortB==1,-1,0);

CurrentPosition = LFlag+SFlag;

---

因為 AB 在語法上沒 power/easy language 這麼簡單寫

小弟這個方法很笨，就是只有簡單的判斷

buy 多單 倉位為 1
short 空單 倉位為 -1

sell 多單平倉 cover 空單平倉 倉位為 0


AB 同好們再參考看看了，有更好的寫法也請大家分享一下唷

再次感謝 enochyu 大大

GnuHomot

回復 1# enochyu

先感謝enochyu大的分享
  

1.     if ( ( _EntryLong ) AND ( _CurrentContracts <= 0 ) )
   
2.     {
   
3.         _CurrentContracts = _ContractUnit;
   
4.         _OrderPrice       = Close[ i ];
   
5.         _LongSharp[ i ]   = True;
   
6.     }

複製代碼

如果小弟沒誤會的話，這段程式碼看起來只有計算到單次進出。
另外因為實際上線時，會影響下單大師的只有最後一根K棒，所以其實for迴圈不用從0開始算，檢查最後一根K棒就可以了。如果要算加碼最後的總部位，又要用另外的算法了。

順便借這篇問一下，該不會全COCO討論區只有我是用Amibroker+下單大師萬用API在下單吧，似乎大家都用文字檔在下單

enochyu

讚啦，希望起拋磚引玉之效 ~ 有機會教學相長

哈哈 ~ 小弟就是用這最笨的方法來控制策略加減碼、停損/停利、折返停利...等機制，還請各位高手們多多指點，一來讓小弟學習成長，二來造福有需要的 AmiBroker 戰友們 ~

感恩啦

enochyu

回復 3# GnuHomot


目前小弟也是 AB + 下單大師配合使用中，只是部分策略會另輸出一份文字檔給雅X紀錄器做紀錄，請多多指教了。

lu0811

讚啦～感謝分享 :)

lutin111

謝謝了...........感謝分享 :)

yfbook

感谢分享，……谢谢

enochyu

程式範例分享 ~ AmiBroker 控制下單口數、使用下單大師、輸出文字檔



------

祝各位 AmiBroker 戰友順心 ...
enochyu 發表於 11-12-30 12:43 AM

來個小改版，簡化不必要之程式碼(如：for loop)達到一樣的效果，請參考囉

1. 
   
2. //
   
3. // title
   
4. //
   
5. SetChartOptions( 0, chartShowArrows | chartShowDates | chartWrapTitle );
   
6. _N(  Title = StrFormat( "{{NAME}} - {{DATE}}   O %g,   H %g,   L %g,   C %g,  (%.1f%%)", O, H, L, C, SelectedValue( ROC( C, 1 ) ) ) );
   
7. Title = Title + "    [ Go Order Sample ] Create by E.Y. @2012/01/08 \n{{VALUES}}";
   
8. Plot( Day() != Ref( Day(), -1 ), "", ColorRGB( 50, 50, 50 ), styleHistogram | styleOwnScale, 0, 1 );
   
9. 
   
10. 
    
11. // --- >>> START <<<
    
12. // -------------------------------------------------------------------------
    
13. // computation buy, short, sell and cover condition
    
14. // -------------------------------------------------------------------------
    
15. //
    
16. // computation buy, short, sell and cover condition
    
17. //
    
18. _Condition1  = Ref( MA( Close, 3 ), -1 );
    
19. _Condition2  = Ref( MA( Close, 22 ), -1 );
    
20. Buy   = ( _Condition1 > _Condition2 ) AND ( TimeNum() <= 132000 );   // buy condition
    
21. Short = ( _Condition1 < _Condition2 ) AND ( TimeNum() <= 132000 );   // short condition
    
22. Sell  = Cover = ( TimeNum() > 132000 );                // sell and cover condition
    
23. //
    
24. // computation buyprice, shortprice, sellprice and coverprice
    
25. //
    
26. BuyPrice = ShortPrice = SellPrice  = CoverPrice = Close;
    
27. //
    
28. // filter buy, short, sell and cover signal
    
29. //
    
30. _LongEntry  = ExRem( Buy, Short ) OR ExRem( Buy, Sell );
    
31. _ShortEntry = ExRem( Short, Buy ) OR ExRem( Short, Cover );
    
32. _ClearAll   = ( Sell OR Cover ) AND ( Ref( Buy, -1 ) OR Ref( Short, -1 ) );
    
33. //
    
34. // -------------------------------------------------------------------------
    
35. // computation buy, short, sell and cover condition
    
36. // -------------------------------------------------------------------------
    
37. // --- >>> END <<<
    
38. 
    
39. 
    
40. // --- >>> START <<<
    
41. // -------------------------------------------------------------------------
    
42. // computation order date, time, contracts, price
    
43. // -------------------------------------------------------------------------
    
44. //
    
45. // contracts per order
    
46. //
    
47. _TXFContractUnit   = 1;
    
48. //
    
49. // txf order contracts
    
50. //
    
51. _TXFOrderContracts = IIf( Sell OR Cover
    
52.                             // sell or cover contracts
    
53.                             , 0                             
    
54.                             , IIf( Buy
    
55.                                    // buy contracts
    
56.                                    , _TXFContractUnit
    
57.                                    // short contracts
    
58.                                    , _TXFContractUnit * -1
    
59.                                  )
    
60.                           );
    
61. _TXFOrderPrice     = Close;
    
62. //
    
63. // -------------------------------------------------------------------------
    
64. // computation order contracts, price
    
65. // -------------------------------------------------------------------------
    
66. // --- >>> END <<<
    
67. 
    
68. 
    
69. // --- >>> START <<<
    
70. // -------------------------------------------------------------------------
    
71. // go order
    
72. // -------------------------------------------------------------------------
    
73. //
    
74. // prepare go order parameters
    
75. //
    
76. _GoOrderContracts = _TXFOrderContracts;
    
77. _GoOrderPrice     = _TXFOrderPrice;
    
78. _GoOrderNowDate   = Now( 1 );
    
79. _GoOrderNowTime   = StrRight( "00" + floor( Now( 4 ) / 10000 ), 2 )
    
80.                     + ":" + StrRight( "00" + floor( Now( 4 ) / 100 ), 2 )
    
81.                     + ":" + StrRight( "00" + floor( Now( 4 ) % 100 ), 2 );
    
82. //
    
83. // sned order command to [ OrderMaster API ]
    
84. //
    
85. _OMComAPI = CreateStaticObject( "OMSignAPI.OMCOMAPI" );
    
86. _OMComAPI.IniDllAndPosition( "EYDEMO", NumToStr( _TXFOrderContracts, 0 ) );
    
87. _OMComAPI.GoOrder( "EYDEMO"
    
88.                  , ""
    
89.                  , _GoOrderNowDate + " " + _GoOrderNowTime
    
90.                  , NumToStr( _GoOrderContracts, 0 )
    
91.                  , NumToStr( _GoOrderPrice, 0 )
    
92.                  );
    
93. //
    
94. // output text file for [YasserSoft] auto record
    
95. //
    
96. _YS_ORDER_CMD = "R:\\YS_TEMP\\EYDEMO.txt";
    
97. if ( ( Now( 4 ) % 2 ) == 0 )
    
98. {
    
99.     _fcsv = fopen( _YS_ORDER_CMD, "w" );
    
100.     _content = _GoOrderNowDate
     
101.              + " " + _GoOrderNowTime
     
102.              + " " + StrFormat( "%g %g", _GoOrderContracts, _GoOrderPrice )
     
103.              + " " + _GoOrderNowTime
     
104.              ;
     
105.     fputs( _content, _fcsv );
     
106.     fclose( _fcsv );
     
107. }
     
108. // -------------------------------------------------------------------------
     
109. // go order
     
110. // -------------------------------------------------------------------------
     
111. // --- >>> END <<<
     
112. 
     
113. 
     
114. // --- >>> START <<<
     
115. // -------------------------------------------------------------------------
     
116. // drawing
     
117. // -------------------------------------------------------------------------
     
118. //
     
119. // draw the ma line
     
120. //
     
121. Plot( _Condition1, "MA1", colorYellow, styleDashed );
     
122. Plot( _Condition2, "MA2", ColorRGB( 0, 80, 255 ), styleDots );
     
123. //
     
124. // draw the buy or short signal
     
125. //
     
126. PlotShapes( _LongEntry * shapeUpArrow + _ShortEntry * shapeDownArrow
     
127.           , IIf( _LongEntry, colorYellow, ColorRGB( 0, 80, 255 ) )
     
128.           , 0
     
129.           , IIf( _LongEntry, Low, High )
     
130.           , -30 );
     
131. //
     
132. // draw the clear signal
     
133. //
     
134. PlotShapes( _ClearAll * shapeSmallCircle
     
135.           , colorLightGrey
     
136.           , 0
     
137.           , Close
     
138.           , -30 );
     
139. PlotShapes( _ClearAll * shapeHollowSquare
     
140.           , colorLightGrey
     
141.           , 0
     
142.           , Close
     
143.           , -30 );
     
144. //
     
145. // draw the candle line
     
146. //
     
147. Plot( Close
     
148.     , "Close"
     
149.     , ParamColor( "Color", colorBlack )
     
150.     , styleNoTitle | ParamStyle( "Style" ) | GetPriceStyle() );
     
151. //
     
152. //
     
153. //
     
154. Title = Title + EncodeColor( colorGold ) + "    ( " + _GoOrderContracts + ", " + _GoOrderPrice + " )";
     
155. //
     
156. // -------------------------------------------------------------------------
     
157. // drawing
     
158. // -------------------------------------------------------------------------
     
159. // --- >>> END <<<
     

複製代碼

相信以各位大大功力一看就懂，小弟在此就不在贅述了

轉載至 C.A.B.E.

calvinhorng

感谢分享，……谢谢

f29825604

感謝分享
感激不盡

usana642

enochyu 發表於 12-1-9 00:47
來個小改版，簡化不必要之程式碼(如：for loop)達到一樣的效果，請參考囉

請問將此程式碼在5分線執行時,在現K棒還未完成收定時,買賣條件忽多忽空,造成重複下單,請問要如何解決?謝謝您

Kreangast

So

_Condition1  = Ref( MA( Close, 5 ), -1 );
_Condition2  = Ref( MA( Close, 60 ), -1 );
Buy   = ( _Condition1 > _Condition2 ); //AND ( TimeNum() <= 132000 ); buy condition
Short = ( _Condition1 < _Condition2 ) ;//AND ( TimeNum() <= 132000 ); short condition
Sell  = Cover = ( TimeNum() > 0);                // sell and cover condition

主要改了下開單時間,均線參數,圖上尖頭信號真多,請指正哪裏錯了...謝謝